3D objects: DrawObject (Part 4 of 5)

       Name: DrawObject (Part 4 of 5)                                [Show more]
       Type: Subroutine
   Category: 3D objects
    Summary: Draw the shadow for each of the object's faces
  Deep dive: Drawing 3D objects
             Object blueprints
    Context: See this subroutine in context in the source code
 References: No direct references to this subroutine in this source file


 CMP     R1, #0                     \ If R1 is positive, then the y-coordinate
 BPL     dobj4                      \ of the rotated normal vector is positive,
                                    \ which means it is pointing down, so jump
                                    \ to dobj4 to skip drawing the shadow for
                                    \ this face, as we only draw shadows for
                                    \ faces that point up, like the roof of the
                                    \ gazebo

 LDRB    R14, [R11, #objectFlags]   \ If bit 1 of objectFlags is zero then this
 TST     R14, #%00000010            \ object is configured not to have a shadow,
 BEQ     dobj4                      \ so jump to dobj4 to skip the following

                                    \ We now draw the object's shadow into the
                                    \ graphics buffers

 STMFD   R13!, {R3, R9, R11}        \ Store the registers that we want to use on
                                    \ the stack so they can be preserved

 LDMIA   R9, {R5-R7}                \ Set R5, R6, R7 to the fourth, fifth and
                                    \ sixth words of the face data, which
                                    \ contain the numbers of the vertices that
                                    \ make up the face

 MOV     R8, #0                     \ Set R8 = 0, which we will pass to the
                                    \ DrawTriangleShadowToBuffer routine as the
                                    \ face colour, so the shadow is drawn in
                                    \ black

 ADD     R10, R11, #vertexProjected \ Set R10 to the address of the third word
 ADD     R10, R10, #8               \ in vertexProjected
                                    \
                                    \ For each vertex we wrote two coordinates
                                    \ to vertexProjected, with the second being
                                    \ the shadow's projected coordinates, so
                                    \ this sets R10 to the address of the second
                                    \ projected coordinate's pixel x-coordinate,
                                    \ i.e. the pixel coordinate for the shadow
                                    \ of the first object vertex

 ADD     R5, R10, R5, LSL #4        \ Set (R0, R1) to the two words at offset
 LDMIA   R5, {R0-R1}                \ R5 * 16 from the table at R10, which is
                                    \ the pixel coordinate of the shadow for the
                                    \ vertex number in R5, i.e. the first vertex
                                    \ in this face
                                    \
                                    \ We multiply the vertex number by 16 as
                                    \ there are four words per vertex in
                                    \ vertexProjected, which is 16 bytes per
                                    \ face

 ADD     R6, R10, R6, LSL #4        \ Set (R2, R3) to the two words at offset
 LDMIA   R6, {R2-R3}                \ R6 * 16 from the table at R10, which is
                                    \ the pixel coordinate of the shadow for the
                                    \ vertex number in R6, i.e. the second
                                    \ vertex in this face

 ADD     R7, R10, R7, LSL #4        \ Set (R4, R5) to the two words at offset
 LDMIA   R7, {R4-R5}                \ R7 * 16 from the table at R10, which is
                                    \ the pixel coordinate of the shadow for the
                                    \ vertex number in R7, i.e. the third vertex
                                    \ in this face

 BL      DrawTriangleShadowToBuffer \ Draw the triangle that shows the shadow
                                    \ for this face, which uses the vertices of
                                    \ the face, dropped directly down onto the
                                    \ landscape, all drawn in black

 LDMFD   R13!, {R3, R9, R11}        \ Retrieve the registers that we stored on
                                    \ the stack