Skip to navigation

⌂ ∞ Lander on the Acorn Archimedes

Score bar: PrintCurrentScore

       Name: PrintCurrentScore                                       [Show more]
       Type: Subroutine
   Category: Score bar
    Summary: Print the current score at the left end of the score bar

    Context: See this subroutine in context in the source code
 References: This subroutine is called as follows:
             * LoseLife calls PrintCurrentScore
             * MainLoop calls PrintCurrentScore




.PrintCurrentScore

 LDR     R0, [R11, #currentScore]   \ Set R0 to the current score

 ADD     R1, R11, #stringBuffer     \ Set R1 = stringBuffer to use as a string
                                    \ buffer for the following call

 MOV     R2, #19                    \ Set R2 = 19, to use as the size of the
                                    \ string buffer in the following call

 CMP     R0, #1024                  \ If R0 >= 1024, set gravity = &50000, so
 MOVHS   R4, #&50000                \ gravity increases from the starting value
 STRHS   R4, [R11, #gravity]        \ of &30000 when we reach a score of 1024

 CMP     R0, #1488                  \ If R0 >= 1488, set gravity = &70000, so
 MOVHS   R4, #&70000                \ gravity increases again when we reach a
 STRHS   R4, [R11, #gravity]        \ score of 1488

 SWI     OS_BinaryToDecimal         \ Convert the unsigned number in R0 to a
                                    \ string and store it in the buffer at R1
                                    \ with a maximum string size of R2

 MOV     R0, #30                    \ Print a VDU 30 command to move the text
 SWI     OS_WriteC                  \ cursor to the top-left corner of the
                                    \ screen

 MOV     R0, #&0A                   \ Print a line feed (ASCII &0A) to move the
 SWI     OS_WriteC                  \ cursor down one line, to the start of the
                                    \ second line, which is where we print the
                                    \ score bar

                                    \ We now print the contents of the string
                                    \ buffer, which updates the number of
                                    \ remaining bullets on-screen

.prsc1

 LDRB    R0, [R1], #1               \ Print the character in the buffer at R1,
 SWI     OS_WriteC                  \ incrementing R1 as we go

 SUBS    R2, R2, #1                 \ Decrement the loop counter in R2

 BNE     prsc1                      \ Loop back to print the next character from
                                    \ the buffer until we have printed all R2 of
                                    \ them

 MOV     R0, #&20                   \ Print two spaces (ASCII &20) to ensure we
 SWI     OS_WriteC                  \ remove any characters from the previous
 SWI     OS_WriteC                  \ bullet count

 MOV     PC, R14                    \ Return from the subroutine