Score bar: PrintScoreInBothBanks

       Name: PrintScoreInBothBanks                                   [Show more]
       Type: Subroutine
   Category: Score bar
    Summary: Print a number at a specified text column in the score bar
    Context: See this subroutine in context in the source code
 References: This subroutine is called as follows:
             * PlacePlayerOnLaunchpad calls PrintScoreInBothBanks
             * StartNewGame calls PrintScoreInBothBanks


 Arguments:

   R0                               The unsigned number to print

   R1                               Text column (x-coordinate)

   R2                               Text row (y-coordinate)


.PrintScoreInBothBanks

 STMFD   R13!, {R1-R2}              \ Store the arguments in R1 and R2 on the
                                    \ stack so can retrieve them below

 ADD     R1, R11, #stringBuffer     \ Set R1 = stringBuffer to use as a string
                                    \ buffer for the following call

 MOV     R2, #19                    \ Set R2 = 19, to use as the size of the
                                    \ string buffer in the following call

 SWI     OS_BinaryToDecimal         \ Convert the unsigned number in R0 to a
                                    \ string and store it in the buffer at R1
                                    \ with a maximum string size of R2

 MOV     R0, #31                    \ Start printing the following VDU command:
 SWI     OS_WriteC                  \
                                    \   VDU 31, x, y
                                    \
                                    \ which moves the text cursor to column x
                                    \ on row y

 LDMFD   R13!, {R3-R4}              \ Fetch R1 and R2 into R3 and R4 and write
 MOV     R0, R3                     \ them to complete the VDU 31 command, so
 SWI     OS_WriteC                  \ this moves the text cursor to the position
 MOV     R0, R4                     \ defined in the subroutine arguments,
 SWI     OS_WriteC                  \ leaving the text coordinates in (R3, R4)

 STMFD   R13!, {R1-R2}              \ Store R1 and R2 on the stack so we can
                                    \ preserve them through the following
                                    \ OS_Byte call

 MOV     R0, #112                   \ Set the VDU driver screen bank to bank 1
 MOV     R1, #1
 SWI     OS_Byte

 LDMFD   R13, {R1-R2}               \ Retrieve R1 and R2 from the stack, so R1
                                    \ points to the string buffer and R2 is the
                                    \ buffer size
                                    \
                                    \ Note that we don't update the stack
                                    \ pointer, so we can retrieve them again
                                    \ below

.prsb1

 LDRB    R0, [R1], #1               \ Print the character in the buffer at R1,
 SWI     OS_WriteC                  \ incrementing R1 as we go

 SUBS    R2, R2, #1                 \ Decrement the loop counter in R2

 BNE     prsb1                      \ Loop back to print the next character from
                                    \ the buffer until we have printed all R2 of
                                    \ them

 MOV     R0, #112                   \ Set the hardware and VDU screen banks to
 MOV     R1, #2                     \ screen bank 1
 SWI     OS_Byte

 MOV     R0, #31                    \ Print the following VDU command:
 SWI     OS_WriteC                  \
 MOV     R0, R3                     \   VDU 31, R3, R4
 SWI     OS_WriteC                  \
 MOV     R0, R4                     \ which moves the text cursor to column R3
 SWI     OS_WriteC                  \ on row R4, i.e. the same text coordinates
                                    \ as the text we printed in screen bank 1
                                    \ above

 LDMFD   R13!, {R1-R2}              \ Retrieve R1 and R2 from the stack, so R1
                                    \ points to the string buffer and R2 is the
                                    \ buffer size

.prsb2

 LDRB    R0, [R1], #1               \ Print the character in the buffer at R1,
 SWI     OS_WriteC                  \ incrementing R1 as we go

 SUBS    R2, R2, #1                 \ Decrement the loop counter in R2

 BNE     prsb2                      \ Loop back to print the next character from
                                    \ the buffer until we have printed all R2 of
                                    \ them

 MOV     PC, R14                    \ Return from the subroutine